4 Declarations and Bindings

In this chapter, we describe the syntax and informal semantics of Haskell declarations.

The declarations in the syntactic category $$ \text{𝑡𝑜𝑝𝑑𝑒𝑐𝑙𝑠}$$ are only allowed at the top level of a Haskell module (see Chapter 5), whereas $$ \text{𝑑𝑒𝑐𝑙𝑠}$$ may be used either at the top level or in nested scopes (i.e. those within a let or where construct).

For exposition, we divide the declarations into three groups: user-defined datatypes, consisting of type, newtype, and data declarations (Section 4.2); type classes and overloading, consisting of class, instance, and default declarations (Section 4.3); and nested declarations, consisting of value bindings, type signatures, and fixity declarations (Section 4.4).

Haskell has several primitive datatypes that are “hard-wired” (such as integers and floating-point numbers), but most “built-in” datatypes are defined with normal Haskell code, using normal type and data declarations. These “built-in” datatypes are described in detail in Section 6.1.

4.1 Overview of Types and Classes

Haskell uses a traditional Hindley-Milner polymorphic type system to provide a static type semantics [4], [5], but the type system has been extended with type classes (or just classes) that provide a structured way to introduce overloaded functions.

A class declaration (Section 4.3.1) introduces a new type class and the overloaded operations that must be supported by any type that is an instance of that class. An instance declaration (Section 4.3.2) declares that a type is an instance of a class and includes the definitions of the overloaded operations—called class methods—instantiated on the named type.

For example, suppose we wish to overload the operations (+) and negate on types Int and Float. We introduce a new type class called Num:

  class Num a  where          -- simplified class declaration for Num
    (+)    :: a -> a -> a     -- (Num is defined in the Prelude)
    negate :: a -> a

This declaration may be read “a type a is an instance of the class Num if there are class methods (+) and negate, of the given types, defined on it.”“

We may then declare Int and Float to be instances of this class:

  instance Num Int  where     -- simplified instance of Num Int
    x + y       =  addInt x y
    negate x    =  negateInt x
  
  instance Num Float  where   -- simplified instance of Num Float
    x + y       =  addFloat x y
    negate x    =  negateFloat x

where addInt, negateInt, addFloat, and negateFloat are assumed in this case to be primitive functions, but in general could be any user-defined function. The first declaration above may be read “Int is an instance of the class Num as witnessed by these definitions (i.e. class methods) for (+) and negate.”

More examples of type classes can be found in the papers by Jones [6] or Wadler and Blott [7]. The term “type class” was used to describe the original Haskell 1.0 type system; “constructor class” was used to describe an extension to the original type classes. There is no longer any reason to use two different terms: in this report, “type class” includes both the original Haskell type classes and the constructor classes introduced by Jones.

4.1.1 Kinds

To ensure that they are valid, type expressions are classified into different kinds, which take one of two possible forms:

• The symbol $\ast$ represents the kind of all nullary type constructors.
• If ${𝜅}_1$ and ${𝜅}_2$ are kinds, then ${𝜅}_1\to {𝜅}_2$ is the kind of types that take a type of kind ${𝜅}_1$ and return a type of kind ${𝜅}_2$.

Kind inference checks the validity of type expressions in a similar way that type inference checks the validity of value expressions. However, unlike types, kinds are entirely implicit and are not a visible part of the language. Kind inference is discussed in Section 4.6.

4.1.2 Syntax of Types

The syntax for Haskell type expressions is given above. Just as data values are built using data constructors, type values are built from type constructors. As with data constructors, the names of type constructors start with uppercase letters. Unlike data constructors, infix type constructors are not allowed (other than (->)).

The main forms of type expression are as follows:

1. Type variables, written as identifiers beginning with a lowercase letter. The kind of a variable is determined implicitly by the context in which it appears.

2. Type constructors. Most type constructors are written as an identifier beginning with an uppercase letter. For example:

   • Char, Int, Integer, Float, Double and Bool are type constants with kind $\ast$.
   • Maybe and IO are unary type constructors, and treated as types with kind $\ast \to \ast$.
   • The declarations data T ... or newtype T ... add the type constructor T to the type vocabulary. The kind of T is determined by kind inference.

   Special syntax is provided for certain built-in type constructors:

   • The trivial type is written as () and has kind $\ast$. It denotes the “nullary tuple” type, and has exactly one value, also written () (see Section 3.9 and Section 6.1.5).
   • The function type is written as (->) and has kind $\ast \to \ast \to \ast$.
   • The list type is written as [] and has kind $\ast \to \ast$.
   • The tuple types are written as (,), (,,), and so on. Their kinds are $\ast \to \ast \to \ast$,$\ast \to \ast \to \ast \to \ast$, and so on.

   Use of the (->) and [] constants is described in more detail below.

3. Type application. If ${𝑡}_1$ is a type of kind ${𝜅}_1\to {𝜅}_2$ and ${𝑡}_2$ is a type of kind ${𝜅}_1$, then ${𝑡}_1{𝑡}_2$ is a type expression of kind ${𝜅}_2$.

4. A parenthesized type, having form $\left(𝑡\right)$, is identical to the type $𝑡$.

For example, the type expression IO a can be understood as the application of a constant, IO, to the variable a. Since the IO type constructor has kind $\ast \to \ast$, it follows that both the variable a and the whole expression, IO a, must have kind $\ast$. In general, a process of kind inference (see Section 4.6) is needed to determine appropriate kinds for user-defined datatypes, type synonyms, and classes.

Special syntax is provided to allow certain type expressions to be written in a more traditional style:

1. A function type has the form ${𝑡}_1\to {𝑡}_2$, which is equivalent to the type $(\to ){𝑡}_1{𝑡}_2$. Function arrows associate to the right. For example, Int -> Int -> Float means Int -> (Int -> Float).
2. A tuple type has the form $\left({𝑡}_1,\dots ,{𝑡}_{𝑘}\right)$, where $𝑘\ge 2$, which is equivalent to the type $\left(,\dots ,\right){𝑡}_1\dots {𝑡}_{𝑘}$ where there are $𝑘-1$ commas between the parenthesis. It denotes the type of $𝑘$-tuples with the first component of type ${𝑡}_1$, the second component of type ${𝑡}_2$, and so on (see Section 3.8 and Section 6.1.4).
3. A list type has the form $\left[𝑡\right]$, which is equivalent to the type $\left[\right]𝑡$. It denotes the type of lists with elements of type $𝑡$ (see Section 3.7 and Section 6.1.3).

These special syntactic forms always denote the built-in type constructors for functions, tuples, and lists, regardless of what is in scope. In a similar way, the prefix type constructors (->), [], (), (,), and so on, always denote the built-in type constructors; they cannot be qualified, nor mentioned in import or export lists (Chapter 5). (Hence the special production, “gtycon”, above.)

Although the list and tuple types have special syntax, their semantics is the same as the equivalent user-defined algebraic data types.

Notice that expressions and types have a consistent syntax. If ${𝑡}_{𝑖}$ is the type of expression or pattern ${𝑒}_{𝑖}$, then the expressions (\ e1 -> e2), [e1], and (t1 -> t2), [t1], and (t1, t2), respectively.

With one exception (that of the distinguished type variable in a class declaration (Section 4.3.1)), the type variables in a Haskell type expression are all assumed to be universally quantified; there is no explicit syntax for universal quantification [5]. For example, the type expression a -> a denotes the type $\forall 𝑎.𝑎\to 𝑎$. For clarity, however, we often write quantification explicitly when discussing the types of Haskell programs. When we write an explicitly quantified type, the scope of the $\forall$ extends as far to the right as possible; for example, $\forall 𝑎.𝑎\to 𝑎$ means $\forall 𝑎.\left(𝑎\to 𝑎\right)$.

4.1.3 Syntax of Class Assertions and Contexts

A class assertion has form $\text{𝑞𝑡𝑦𝑐𝑙𝑠}\text{𝑡𝑦𝑣𝑎𝑟}$, and indicates the membership of the type $\text{𝑡𝑦𝑣𝑎𝑟}$ in the class $\text{𝑞𝑡𝑦𝑐𝑙𝑠}$. A class identifier begins with an uppercase letter. A context consists of zero or more class assertions, and has the general form

where ${𝐶}_1,\dots ,{𝐶}_{𝑛}$ are class identifiers, and each of the ${𝑢}_1,\dots ,{𝑢}_{𝑛}$ is either a type variable, or the application of type variable to one or more types. The outer parentheses may be omitted when $𝑛=1$. In general, we use $\text{𝑐𝑥}$ to denote a context and we write $\text{𝑐𝑥}\text{=>}𝑡$ to indicate the type $𝑡$ restricted by the context $\text{𝑐𝑥}$. The context $\text{𝑐𝑥}$ must only contain type variables referenced in $𝑡$. For convenience, we write $\text{𝑐𝑥}\text{=>}𝑡$ even if the context $\text{𝑐𝑥}$ is empty, although in this case the concrete syntax contains no =>.

4.1.4 Semantics of Types and Classes

In this section, we provide informal details of the type system. (Wadler and Blott [7] and Jones [6] discuss type and constructor classes, respectively, in more detail.)

The Haskell type system attributes a type to each expression in the program. In general, a type is of the form $\forall \stackrel{<mtext>\_</mtext>}{𝑢}.\text{𝑐𝑥}\Rightarrow 𝑡$, where $\stackrel{<mtext>\_</mtext>}{𝑢}$ is a set of type variables ${𝑢}_1,\dots ,{𝑢}_{𝑛}$. In any such type, any of the universally-quantified type variables ${𝑢}_{𝑖}$ that are free in $\text{𝑐𝑥}$ must also be free in $𝑡$. Furthermore, the context $\text{𝑐𝑥}$ must be of the form given above in Section 4.1.3. For example, here are some valid types:

  Eq a => a -> a
  (Eq a, Show a, Eq b) => [a] -> [b] -> String
  (Eq (f a), Functor f) => (a -> b) -> f a -> f b -> Bool

In the third type, the constraint Eq (f a) cannot be made simpler because f is universally quantified.

The type of an expression $𝑒$ depends on a type environment that gives types for the free variables in $𝑒$, and a class environment that declares which types are instances of which classes (a type becomes an instance of a class only via the presence of an instance declaration or a deriving clause).

Types are related by a generalization preorder (specified below); the most general type, up to the equivalence induced by the generalization preorder, that can be assigned to a particular expression (in a given environment) is called its principal type. Haskell’s extended Hindley-Milner type system can infer the principal type of all expressions, including the proper use of overloaded class methods (although certain ambiguous overloadings could arise, as described in Section 4.3.4). Therefore, explicit typings (called type signatures) are usually optional (see Section 3.16 and Section 4.4.1).

The type $\forall \stackrel{<mtext>\_</mtext>}{𝑢}.{\text{𝑐𝑥}}_1\Rightarrow {𝑡}_1$ more general than the type $\forall \stackrel{<mtext>\_</mtext>}{𝑤}.{\text{𝑐𝑥}}_2\Rightarrow {𝑡}_2$ if and only if there is a substitution $𝑆$ whose domain is $\stackrel{<mtext>\_</mtext>}{𝑢}$ such that:

• ${𝑡}_2$ is identical to $𝑆\left({𝑡}_1\right)$.
• Whenever ${\text{𝑐𝑥}}_2$ holds in the class environment, $𝑆\left({\text{𝑐𝑥}}_1\right)$ also holds.

A value of type $\forall \stackrel{<mtext>\_</mtext>}{𝑢}.\text{𝑐𝑥}\Rightarrow 𝑡$, may be instantiated at types $\stackrel{<mtext>\_</mtext>}{𝑠}$ if and only if the context $\text{𝑐𝑥}\left[\frac{\stackrel{<mtext>\_</mtext>}{𝑠}}{\stackrel{<mtext>\_</mtext>}{𝑢}}\right]$ holds. For example, consider the function double:

double x = x + x

The most general type of double is $\forall 𝑎.\text{𝙽𝚞𝚖}𝑎\Rightarrow 𝑎\to 𝑎$. double may be applied to values of type Int (instantiating $𝑎$ to Int), since Num Int holds, because Int is an instance of the class Num. However, double may not normally be applied to values of type Char, because Char is not normally an instance of class Num. The user may choose to declare such an instance, in which case double may indeed be applied to a Char.

4.2 User-Defined Datatypes

In this section, we describe algebraic datatypes (data declarations), renamed datatypes (newtype declarations), and type synonyms (type declarations). These declarations may only appear at the top level of a module.

4.2.1 Algebraic Datatype Declarations

The precedence for $\text{𝑐𝑜𝑛𝑠𝑡𝑟}$ is the same as that for expressions—normal constructor application has higher precedence than infix constructor application (thus a : Foo a parses as a : (Foo a)).

An algebraic datatype declaration has the form:

where $\text{𝑐𝑥}$ is a context. This declaration introduces a new type constructor $𝑇$ with zero or more constituent data constructors ${𝐾}_1,\dots {𝐾}_{𝑛}$. In this Report, the unqualified term “constructor” always means “data constructor”.

The types of the data constructors are given by:

where ${\text{𝑐𝑥}}_{𝑖}$ is the largest subset of $\text{𝑐𝑥}$ that constrains only those type variables free in the types ${𝑡}_{𝑖1}\dots {𝑡}_{𝑖{𝑘}_{𝑖}}$. The type variables ${𝑢}_1$ through ${𝑢}_{𝑘}$ must be distinct and may appear in $\text{𝑐𝑥}$ and the ${𝑡}_{𝑖𝑗}$; it is a static error for any other type variable to appear in $\text{𝑐𝑥}$ or on the right-hand-side. The new type constant $𝑇$ has a kind of the form ${𝜅}_1\to \dots \to {𝜅}_{𝑘}\to \ast$ where the kinds ${𝜅}_{𝑖}$ of the argument variables ${𝑢}_{𝑖}$ are determined by kind inference as described in Section 4.6. This means that $𝑇$ may be used in type expressions with anywhere between $0$ and $𝑘$ arguments.

For example, the declaration

data Eq a => Set a = NilSet | ConsSet a (Set a)

introduces a type constructor Set of kind $\ast \to \ast$, and constructors NilSet and ConsSet with types

In the example given, the overloaded type for ConsSet ensures that ConsSet can only be applied to values whose type is an instance of the class Eq. Pattern matching against ConsSet also gives rise to an Eq a constraint. For example:

  f (ConsSet a s) = a

the function f has inferred type Eq a => Set a -> a. The context in the data declaration has no other effect whatsoever.

The visibility of a datatype’s constructors (i.e. the “abstractness” of the datatype) outside of the module in which the datatype is defined is controlled by the form of the datatype’s name in the export list as described in Section 5.8.

The optional deriving part of a data declaration has to do with derived instances, and is described in Section 4.3.3.

Labelled Fields A data constructor of arity $𝑘$ creates an object with $𝑘$ components. These components are normally accessed positionally as arguments to the constructor in expressions or patterns. For large datatypes it is useful to assign field labels to the components of a data object. This allows a specific field to be referenced independently of its location within the constructor.

A constructor definition in a data declaration may assign labels to the fields of the constructor, using the record syntax ($𝐶\left\{\dots \right\}$). Constructors using field labels may be freely mixed with constructors without them. A constructor with associated field labels may still be used as an ordinary constructor; features using labels are simply a shorthand for operations using an underlying positional constructor. The arguments to the positional constructor occur in the same order as the labeled fields. For example, the declaration

  data C = F { f1,f2 :: Int, f3 :: Bool }

defines a type and constructor identical to the one produced by

  data C = F Int Int Bool

Operations using field labels are described in Section 3.15. A data declaration may use the same field label in multiple constructors as long as the typing of the field is the same in all cases after type synonym expansion. A label cannot be shared by more than one type in scope. Field names share the top level namespace with ordinary variables and class methods and must not conflict with other top level names in scope.

The pattern F { } matches any value built with constructor F, whether or not F was declared with record syntax.

Strictness Flags Whenever a data constructor is applied, each argument to the constructor is evaluated if and only if the corresponding type in the algebraic datatype declaration has a strictness flag, denoted by an exclamation point, “!”. Lexically, “!” is an ordinary varsym not a $$ \text{𝑟𝑒𝑠𝑒𝑟𝑣𝑒𝑑𝑜𝑝}$$; it has special significance only in the context of the argument types of a data declaration.

4.2.2 Type Synonym Declarations

A type synonym declaration introduces a new type that is equivalent to an old type. It has the form

which introduces a new type constructor, $𝑇$. The type $\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)$ is equivalent to the type $𝑡\left[{𝑡}_1\text{/}{𝑢}_1,\dots ,{𝑡}_{𝑘}\text{/}{𝑢}_{𝑘}\right]$. The type variables ${𝑢}_1$ through ${𝑢}_{𝑘}$ must be distinct and are scoped only over $𝑡$; it is a static error for any other type variable to appear in $𝑡$. The kind of the new type constructor $𝑇$ is of the form ${𝜅}_1\to \dots \to {𝜅}_{𝑘}\to 𝜅$ where the kinds ${𝜅}_{𝑖}$ of the arguments ${𝑢}_{𝑖}$ and $𝜅$ of the right hand side $𝑡$ are determined by kind inference as described in Section 4.6. For example, the following definition can be used to provide an alternative way of writing the list type constructor:

type List = []

Type constructor symbols $𝑇$ introduced by type synonym declarations cannot be partially applied; it is a static error to use $𝑇$ without the full number of arguments.

Although recursive and mutually recursive datatypes are allowed, this is not so for type synonyms, unless an algebraic datatype intervenes. For example,

  type Rec a   =  [Circ a]
  data Circ a  =  Tag [Rec a]

is allowed, whereas

  type Rec a   =  [Circ a]        -- invalid
  type Circ a  =  [Rec a]         -- invalid

is not. Similarly, type Rec a = [Rec a] is not allowed.

Type synonyms are a convenient, but strictly syntactic, mechanism to make type signatures more readable. A synonym and its definition are completely interchangeable, except in the instance type of an instance declaration (Section 4.3.2).

4.2.3 Datatype Renamings

A declaration of the form

introduces a new type whose representation is the same as an existing type. The type $\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)$ renames the datatype $𝑡$. It differs from a type synonym in that it creates a distinct type that must be explicitly coerced to or from the original type. Also, unlike type synonyms, newtype may be used to define recursive types. The constructor $𝑁$ in an expression coerces a value from type t to type $\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)$. Using $𝑁$ in a pattern coerces a value from type $\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)$ to type $𝑡$. These coercions may be implemented without execution time overhead; newtype does not change the underlying representation of an object.

New instances (see Section 4.3.2) can be defined for a type defined by newtype but may not be defined for a type synonym. A type created by newtype differs from an algebraic datatype in that the representation of an algebraic datatype has an extra level of indirection. This difference may make access to the representation less efficient. The difference is reflected in different rules for pattern matching (see Section 3.17). Unlike algebraic datatypes, the newtype constructor $𝑁$ is unlifted, so that $𝑁\perp$ is the same as $\perp$.

The following examples clarify the differences between data (algebraic datatypes), type (type synonyms), and newtype (renaming types.) Given the declarations

  data D1 = D1 Int
  data D2 = D2 !Int
  type S = Int
  newtype N = N Int
  d1 (D1 i) = 42
  d2 (D2 i) = 42
  s i = 42
  n (N i) = 42

the expressions $\left(\text{𝚍𝟷}\perp \right)$, $\left(\text{𝚍𝟸}\perp \right)$ and $\left(\text{𝚍𝟸}\left(\text{𝙳𝟸}\perp \right)\right)$ are all equivalent to $\perp$, whereas $\left(\text{𝚗}\perp \right)$, $\left(\text{𝚗}\left(\text{𝙽}\perp \right)\right)$, $\left(\text{𝚍𝟷}\left(\text{𝙳𝟷}\perp \right)\right)$ and $\left(\text{𝚜}\perp \right)$ are all equivalent to 42. In particular, $\left(\text{𝙽}\perp \right)$ is equivalent to $\perp$ while $\left(\text{𝙳𝟷}\perp \right)$ is not equivalent to $\perp$.

The optional deriving part of a deriving declaration is treated in the same way as the deriving component of a data declaration; see Section 4.3.3.

A newtype declaration may use field-naming syntax, though of course there may only be one field. Thus:

  newtype Age = Age { unAge :: Int }

brings into scope both a constructor and a de-constructor:

  Age   :: Int -> Age
  unAge :: Age -> Int

4.3 Type Classes and Overloading

4.3.1 Class Declarations

A class declaration introduces a new class and the operations (class methods) on it. A class declaration has the general form:

This introduces a new class name $𝐶$; the type variable $𝑢$ is scoped only over the class method signatures in the class body. The context $\text{𝑐𝑥}$ specifies the superclasses of $𝐶$, as described below; the only type variable that may be referred to in $\text{𝑐𝑥}$ is $𝑢$.

The superclass relation must not be cyclic; i.e. it must form a directed acyclic graph.

The $\text{𝑐𝑑𝑒𝑐𝑙𝑠}$ part of a class declaration contains three kinds of declarations:

• The class declaration introduces new class methods ${𝑣}_{𝑖}$, whose scope extends outside the class declaration. The class methods of a class declaration are precisely the mbox{$𝑖𝑡{𝑣}_{𝑖}$} for which there is an explicit type signature

  $${𝑣}_{𝑖}\text{::}{\text{𝑐𝑥}}_{𝑖}\text{=>}{𝑡}_{𝑖}$$

  in $\text{𝑐𝑑𝑒𝑐𝑙𝑠}$. Class methods share the top level namespace with variable bindings and field names; they must not conflict with other top level bindings in scope. That is, a class method can not have the same name as a top level definition, a field name, or another class method.

  The type of the top-level class method ${𝑣}_{𝑖}$ is:

  $${𝑣}_{𝑖}\text{::}\forall 𝑢,\stackrel{<mtext>\_</mtext>}{𝑤}.\left(𝐶𝑢,{\text{𝑐𝑥}}_{𝑖}\right)\text{=>}{𝑡}_{𝑖}$$

  The ${𝑡}_{𝑖}$ must mention $𝑢$; it may mention type variables $\stackrel{<mtext>\_</mtext>}{𝑤}$ other than $𝑢$, in which case the type of ${𝑣}_{𝑖}$ is polymorphic in both $𝑢$ and $\stackrel{<mtext>\_</mtext>}{𝑤}$. The ${\text{𝑐𝑥}}_{𝑖}$ may constrain only $\stackrel{<mtext>\_</mtext>}{𝑤}$; in particular, the ${\text{𝑐𝑥}}_{𝑖}$ may not constrain $𝑢$. For example:

  class Foo a where
    op :: Num b => a -> b -> a

  Here the type of op is $\forall 𝑎,𝑏.\left(\text{𝙵𝚘𝚘}𝑎,\text{𝙽𝚞𝚖}𝑏\right)\Rightarrow 𝑎\to 𝑏\to 𝑎$.

• The $\text{𝑐𝑑𝑒𝑐𝑙𝑠}$ may also contain a fixity declaration for any of the class methods (but for no other values). However, since class methods declare top-level values, the fixity declaration for a class method may alternatively appear at top level, outside the class declaration.

• Lastly, the $\text{𝑐𝑑𝑒𝑐𝑙𝑠}$ may contain a default class method for any of the ${𝑣}_{𝑖}$. The default class method for ${𝑣}_{𝑖}$ is used if no binding for it is given in a particular instance declaration (see Section 4.3.2). The default method declaration is a normal value definition, except that the left hand side may only be a variable or function definition. For example:

  class Foo a where
    op1, op2 :: a -> a
    (op1, op2) = ...

  is not permitted, because the left hand side of the default declaration is a pattern.

Other than these cases, no other declarations are permitted in $\text{𝑐𝑑𝑒𝑐𝑙𝑠}$.

A class declaration with no where part may be useful for combining a collection of classes into a larger one that inherits all of the class methods in the original ones. For example:

  class  (Read a, Show a) => Textual a

In such a case, if a type is an instance of all superclasses, it is not automatically an instance of the subclass, even though the subclass has no immediate class methods. The instance declaration must be given explicitly with no where part.

4.3.2 Instance Declarations

An instance declaration introduces an instance of a class. Let

be a class declaration. The general form of the corresponding instance declaration is:

where $𝑘\ge 0$. The type $\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)$ must take the form of a type constructor $𝑇$ applied to simple type variables ${𝑢}_1,\dots ,{𝑢}_{𝑘}$; furthermore, $𝑇$ must not be a type synonym, and the ${𝑢}_{𝑖}$ must all be distinct.

This prohibits instance declarations such as:

  instance C (a,a) where ...
  instance C (Int,a) where ...
  instance C [[a]] where ...

The declarations $𝑑$ may contain bindings only for the class methods of $𝐶$. It is illegal to give a binding for a class method that is not in scope, but the name under which it is in scope is immaterial; in particular, it may be a qualified name. (This rule is identical to that used for subordinate names in export lists — Section 5.2.) For example, this is legal, even though range is in scope only with the qualified name Data.Ix.range.

  module A where
    import qualified Data.Ix

    instance Data.Ix.Ix T where
      range = ...

The declarations may not contain any type signatures or fixity declarations, since these have already been given in the class declaration. As in the case of default class methods (Section 4.3.1), the method declarations must take the form of a variable or function definition.

If no binding is given for some class method then the corresponding default class method in the class declaration is used (if present); if such a default does not exist then the class method of this instance is bound to undefined and no compile-time error results.

An instance declaration that makes the type $𝑇$ to be an instance of class $𝐶$ is called a C-T instance declaration and is subject to these static restrictions:

• A type may not be declared as an instance of a particular class more than once in the program.

• The class and type must have the same kind; this can be determined using kind inference as described in Section 4.6.

• Assume that the type variables in the instance type $\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)$ satisfy the constraints in the instance context ${\text{𝑐𝑥}}^{\prime }$. Under this assumption, the following two conditions must also be satisfied:

  1. The constraints expressed by the superclass context $\text{𝑐𝑥}\left[\left(𝑇{𝑢}_1\dots {𝑢}_{𝑘}\right)\text{/}𝑢\right]$ of $𝐶$ must be satisfied. In other words, $𝑇$ must be an instance of each of $𝐶$’s superclasses and the contexts of all superclass instances must be implied by ${\text{𝑐𝑥}}^{\prime }$.
  2. Any constraints on the type variables in the instance type that are required for the class method declarations in $𝑑$ to be well-typed must also be satisfied.

  In fact, except in pathological cases it is possible to infer from the instance declaration the most general instance context ${\text{𝑐𝑥}}^{\prime }$ satisfying the above two constraints, but it is nevertheless mandatory to write an explicit instance context.

The following example illustrates the restrictions imposed by superclass instances:

  class Foo a => Bar a where ...
  
  instance (Eq a, Show a) => Foo [a] where ...
  
  instance Num a => Bar [a] where ...

This example is valid Haskell. Since Foo is a superclass of Bar, the second instance declaration is only valid if [a] is an instance of Foo under the assumption Num a. The first instance declaration does indeed say that [a] is an instance of Foo under this assumption, because Eq and Show are superclasses of Num.

If the two instance declarations instead read like this:

  instance Num a => Foo [a] where ...
  
  instance (Eq a, Show a) => Bar [a] where ...

then the program would be invalid. The second instance declaration is valid only if [a] is an instance of Foo under the assumptions (Eq a, Show a). But this does not hold, since [a] is only an instance of Foo under the stronger assumption Num a.

Further examples of instance declarations may be found in Chapter 9.

4.3.3 Derived Instances

As mentioned in Section 4.2.1, data and newtype declarations contain an optional deriving form. If the form is included, then derived instance declarations are automatically generated for the datatype in each of the named classes. These instances are subject to the same restrictions as user-defined instances. When deriving a class $𝐶$ for a type $𝑇$, instances for all superclasses of $𝐶$ must exist for $𝑇$, either via an explicit instance declaration or by including the superclass in the deriving clause.

Derived instances provide convenient commonly-used operations for user-defined datatypes. For example, derived instances for datatypes in the class Eq define the operations == and /=, freeing the programmer from the need to define them.

The only classes in the Prelude for which derived instances are allowed are Eq, Ord, Enum, Bounded, Show, and Read, all mentioned in Figure 3. The precise details of how the derived instances are generated for each of these classes are provided in Chapter 11, including a specification of when such derived instances are possible. Classes defined by the standard libraries may also be derivable.

A static error results if it is not possible to derive an instance declaration over a class named in a deriving form. For example, not all datatypes can properly support class methods in Enum. It is also a static error to give an explicit instance declaration for a class that is also derived.

If the deriving form is omitted from a data or newtype declaration, then no instance declarations are derived for that datatype; that is, omitting a deriving form is equivalent to including an empty deriving form: deriving ().

4.3.4 Ambiguous Types, and Defaults for Overloaded Numeric Operations

A problem inherent with Haskell-style overloading is the possibility of an ambiguous type. For example, using the read and show functions defined in Chapter 11, and supposing that just Int and Bool are members of Read and Show, then the expression

  let x = read "..." in show x  -- invalid

is ambiguous, because the types for show and read,

could be satisfied by instantiating a as either Int in both cases, or Bool. Such expressions are considered ill-typed, a static error.

We say that an expression e has an ambiguous type if, in its type $\forall \stackrel{<mtext>\_</mtext>}{𝑢}.\text{𝑐𝑥}\Rightarrow 𝑡$, there is a type variable $𝑢$ in $\stackrel{<mtext>\_</mtext>}{𝑢}$ that occurs in $\text{𝑐𝑥}$ but not in $𝑡$. Such types are invalid.

For example, the earlier expression involving show and read has an ambiguous type since its type is $\forall 𝑎.\text{𝚂𝚑𝚘𝚠}𝑎,\text{𝚁𝚎𝚊𝚍}𝑎\Rightarrow \text{𝚂𝚝𝚛𝚒𝚗𝚐}$.

Ambiguous types can only be circumvented by input from the user. One way is through the use of expression type-signatures as described in Section 3.16. For example, for the ambiguous expression given earlier, one could write:

  let x = read "..." in show (x::Bool)

which disambiguates the type.

Occasionally, an otherwise ambiguous expression needs to be made the same type as some variable, rather than being given a fixed type with an expression type-signature. This is the purpose of the function asTypeOf (Chapter 9): x `asTypeOf` y has the value of $𝑥$, but $𝑥$ and $𝑦$ are forced to have the same type. For example,

  approxSqrt x = encodeFloat 1 (exponent x `div` 2) `asTypeOf` x

(See Section 6.4.6 for a description of encodeFloat and exponent.)

Ambiguities in the class Num are most common, so Haskell provides another way to resolve them—with a default declaration:

where $𝑛\ge 0$, and each ${𝑡}_{𝑖}$ must be a type for which $\text{𝙽𝚞𝚖}{𝑡}_{𝑖}$ holds. In situations where an ambiguous type is discovered, an ambiguous type variable, $𝑣$, is defaultable if:

• $𝑣$ appears only in constraints of the form $𝐶𝑣$, where $𝐶$ is a class, and
• at least one of these classes is a numeric class, (that is, Num or a subclass of Num), and
• all of these classes are defined in the Prelude or a standard library (Listing 4 – Listing 5 show the numeric classes, and Figure 3 shows the classes defined in the Prelude.)

Each defaultable variable is replaced by the first type in the default list that is an instance of all the ambiguous variable’s classes. It is a static error if no such type is found.

Only one default declaration is permitted per module, and its effect is limited to that module. If no default declaration is given in a module then it assumed to be:

  default (Integer, Double)

The empty default declaration, default (), turns off all defaults in a module.

4.4 Nested Declarations

The following declarations may be used in any declaration list, including the top level of a module.

4.4.1 Type Signatures

A type signature specifies types for variables, possibly with respect to a context. A type signature has the form:

which is equivalent to asserting ${𝑣}_{𝑖}\text{::}\text{𝑐𝑥}\text{=>}𝑡$ for each $𝑖$ from $1$ to $𝑛$. Each ${𝑣}_{𝑖}$ must have a value binding in the same declaration list that contains the type signature; i.e. it is invalid to give a type signature for a variable bound in an outer scope. Moreover, it is invalid to give more than one type signature for one variable, even if the signatures are identical.

As mentioned in Section 4.1.2, every type variable appearing in a signature is universally quantified over that signature, and hence the scope of a type variable is limited to the type signature that contains it. For example, in the following declarations

f :: a -> a
f x = x :: a                  -- invalid

the a’s in the two type signatures are quite distinct. Indeed, these declarations contain a static error, since x does not have type $\forall 𝑎.𝑎$. (The type of x is dependent on the type of f; there is currently no way in Haskell to specify a signature for a variable with a dependent type; this is explained in Section 4.5.4.)

If a given program includes a signature for a variable $𝑓$, then each use of $𝑓$ is treated as having the declared type. It is a static error if the same type cannot also be inferred for the defining occurrence of $𝑓$.

If a variable $𝑓$ is defined without providing a corresponding type signature declaration, then each use of $𝑓$ outside its own declaration group (see Section 4.5.1) is treated as having the corresponding inferred, or principal type. However, to ensure that type inference is still possible, the defining occurrence, and all uses of $𝑓$ within its declaration group must have the same monomorphic type (from which the principal type is obtained by generalization, as described in Section 4.5.2).

For example, if we define

sqr x  =  x*x

then the principal type is $\text{𝚜𝚚𝚛}\text{::}\forall 𝑎.\text{𝙽𝚞𝚖}𝑎\Rightarrow 𝑎\to 𝑎$, which allows applications such as sqr 5 or sqr 0.1. It is also valid to declare a more specific type, such as

sqr :: Int -> Int

but now applications such as sqr 0.1 are invalid. Type signatures such as

sqr :: (Num a, Num b) => a -> b     -- invalid
sqr :: a -> a                       -- invalid

are invalid, as they are more general than the principal type of sqr.

Type signatures can also be used to support polymorphic recursion. The following definition is pathological, but illustrates how a type signature can be used to specify a type more general than the one that would be inferred:

data T a  =  K (T Int) (T a)
f         :: T a -> a
f (K x y) =  if f x == 1 then f y else undefined

If we remove the signature declaration, the type of f will be inferred as T Int -> Int due to the first recursive call for which the argument to f is T Int. Polymorphic recursion allows the user to supply the more general type signature, T a -> a.

4.4.2 Fixity Declarations

A fixity declaration gives the fixity and binding precedence of one or more operators. The $\text{𝑖𝑛𝑡𝑒𝑔𝑒𝑟}$ in a fixity declaration must be in the range $0$ to $9$. A fixity declaration may appear anywhere that a type signature appears and, like a type signature, declares a property of a particular operator. Also like a type signature, a fixity declaration can only occur in the same sequence of declarations as the declaration of the operator itself, and at most one fixity declaration may be given for any operator. (Class methods are a minor exception; their fixity declarations can occur either in the class declaration itself or at top level.)

There are three kinds of fixity, non-, left- and right-associativity (infix, infixl, and infixr, respectively), and ten precedence levels, 0 to 9 inclusive (level 0 binds least tightly, and level 9 binds most tightly). If the $\text{𝑑𝑖𝑔𝑖𝑡}$ is omitted, level 9 is assumed. Any operator lacking a fixity declaration is assumed to be infixl 9 (See Chapter 3 for more on the use of fixities). Table 1 lists the fixities and precedences of the operators defined in the Prelude.

Fixity is a property of a particular entity (constructor or variable), just like its type; fixity is not a property of that entity’s name. For example:

  module Bar( op ) where
    infixr 7 `op`
    op = ...
  
  module Foo where
    import qualified Bar
    infix 3 `op`
  
    a `op` b = (a `Bar.op` b) + 1
  
    f x = let
             p `op` q = (p `Foo.op` q) * 2
          in ...

Here, `Bar.op` is infixr 7, `Foo.op` is infix 3, and the nested definition of op in f’s right-hand side has the default fixity of infixl 9. (It would also be possible to give a fixity to the nested definition of `op` with a nested fixity declaration.)

4.4.3 Function and Pattern Bindings

We distinguish two cases within this syntax: a pattern binding occurs when the left hand side is a $$ \text{𝑝𝑎𝑡}$$; otherwise, the binding is called a function binding. Either binding may appear at the top-level of a module or within a where or let construct.

4.4.3.1 Function bindings

A function binding binds a variable to a function value. The general form of a function binding for variable $𝑥$ is:

where each ${𝑝}_{𝑖𝑗}$ is a pattern, and where each ${\text{𝑚𝑎𝑡𝑐ℎ}}_{𝑖}$ is of the general form:

or

and where $𝑛\ge 1$, $1\le 𝑖\le 𝑛$, ${𝑚}_{𝑖}\ge 1$. The former is treated as shorthand for a particular case of the latter, namely:

Note that all clauses defining a function must be contiguous, and the number of patterns in each clause must be the same. The set of patterns corresponding to each match must be linear—no variable is allowed to appear more than once in the entire set.

Alternative syntax is provided for binding functional values to infix operators. For example, these three function definitions are all equivalent:

plus x y z = x+y+z
x `plus` y = \ z -> x+y+z
(x `plus` y) z = x+y+z

Note that fixity resolution applies to the infix variants of the function binding in the same way as for expressions (Section 10.6). Applying fixity resolution to the left side of the equals in a function binding must leave the $\text{𝑣𝑎𝑟𝑜𝑝}$ being defined at the top level. For example, if we are defining a new operator ## with precedence 6, then this definition would be illegal:

  a ## b : xs = exp

because : has precedence 5, so the left hand side resolves to (a ## x) : xs, and this cannot be a pattern binding because (a ## x) is not a valid pattern.

4.4.3.2 Pattern bindings

A pattern binding binds variables to values. A simple pattern binding has form $𝑝=𝑒$. The pattern $𝑝$ is matched “lazily” as an irrefutable pattern, as if there were an implicit ~ in front of it. See the translation in Section Section 3.12.

The general form of a pattern binding is $𝑝\text{𝑚𝑎𝑡𝑐ℎ}$, where a $\text{𝑚𝑎𝑡𝑐ℎ}$ is the same structure as for function bindings above; in other words, a pattern binding is:

4.5 Static Semantics of Function and Pattern Bindings

The static semantics of the function and pattern bindings of a let expression or where clause are discussed in this section.

4.5.1 Dependency Analysis

In general the static semantics are given by applying the normal Hindley-Milner inference rules. In order to increase polymorphism, these rules are applied to groups of bindings identified by a dependency analysis.

A binding $𝑏1$ depends on a binding $𝑏2$ in the same list of declarations if either

1. $𝑏1$ contains a free identifier that has no type signature and is bound by $𝑏2$, or
2. $𝑏1$ depends on a binding that depends on $𝑏2$.

A declaration group is a minimal set of mutually dependent bindings. Hindley-Milner type inference is applied to each declaration group in dependency order. The order of declarations in where/let constructs is irrelevant.

4.5.2 Generalization

The Hindley-Milner type system assigns types to a let-expression in two stages:

1. The declaration groups are considered in dependency order. For each group, a type with no universal quantification is inferred for each variable bound in the group. Then, all type variables that occur in these types are universally quantified unless they are associated with bound variables in the type environment; this is called generalization.
2. Finally, the body of the let-expression is typed.

For example, consider the declaration

  f x = let g y = (y,y)
        in ...

The type of g’s definition is $𝑎\to \left(𝑎,𝑎\right)$. The generalization step attributes to g the polymorphic type $\forall 𝑎.𝑎\to \left(𝑎,𝑎\right)$, after which the typing of the “...” part can proceed.

When typing overloaded definitions, all the overloading constraints from a single declaration group are collected together, to form the context for the type of each variable declared in the group. For example, in the definition:

  f x = let g1 x y = if x>y then show x else g2 y x
            g2 p q = g1 q p
        in ...

The types of the definitions of g1 and g2 are both $𝑎\to 𝑎\to \text{𝚂𝚝𝚛𝚒𝚗𝚐}$, and the accumulated constraints are $\text{𝙾𝚛𝚍}𝑎$ (arising from the use of >), and $\text{𝚂𝚑𝚘𝚠}𝑎$ (arising from the use of show). The type variables appearing in this collection of constraints are called the constrained type variables.

The generalization step attributes to both g1 and g2 the type

Notice that g2 is overloaded in the same way as g1 even though the occurrences of > and show are in the definition of g1.

If the programmer supplies explicit type signatures for more than one variable in a declaration group, the contexts of these signatures must be identical up to renaming of the type variables.

4.5.3 Context Reduction Errors

As mentioned in Section 4.1.4, the context of a type may constrain only a type variable, or the application of a type variable to one or more types. Hence, types produced by generalization must be expressed in a form in which all context constraints have be reduced to this “head normal form”. Consider, for example, the definition:

  f xs y  =  xs == [y]

Its type is given by

  f :: Eq a => [a] -> a -> Bool

and not

  f :: Eq [a] => [a] -> a -> Bool

Even though the equality is taken at the list type, the context must be simplified, using the instance declaration for Eq on lists, before generalization. If no such instance is in scope, a static error occurs.

Here is an example that shows the need for a constraint of the form $𝐶\left(𝑚𝑡\right)$ where m is one of the type variables being generalized; that is, where the class $𝐶$ applies to a type expression that is not a type variable or a type constructor. Consider:

  f :: (Monad m, Eq (m a)) => a -> m a -> Bool
  f x y = return x == y

The type of return is Monad m => a -> m a; the type of (==) is Eq a => a -> a -> Bool. The type of f should be therefore (Monad m, Eq (m a)) => a -> m a -> Bool, and the context cannot be simplified further.

The instance declaration derived from a data type deriving clause (see Section 4.3.3) must, like any instance declaration, have a simple context; that is, all the constraints must be of the form $𝐶𝑎$, where $𝑎$ is a type variable. For example, in the type

  data Apply a b = App (a b)  deriving Show

the derived Show instance will produce a context Show (a b), which cannot be reduced and is not simple; thus a static error results.

4.5.4 Monomorphism

Sometimes it is not possible to generalize over all the type variables used in the type of the definition. For example, consider the declaration

  f x = let g y z = ([x,y], z)
        in ...

In an environment where x has type $𝑎$, the type of g’s definition is $𝑎\to 𝑏\to \left(\left[𝑎\right],𝑏\right)$. The generalization step attributes to mbox{tt g} the type $\forall 𝑏.𝑎\to 𝑏\to \left(\left[𝑎\right],𝑏\right)$; only $𝑏$ can be universally quantified because $𝑎$ occurs in the type environment. We say that the type of g is monomorphic in the type variable $𝑎$.

The effect of such monomorphism is that the first argument of all applications of g must be of a single type. For example, it would be valid for the “...” to be

  (g True, g False)

(which would, incidentally, force x to have type Bool) but invalid for it to be

  (g True, g 'c')

In general, a type $\forall \stackrel{<mtext>\_</mtext>}{𝑢}.\text{𝑐𝑥}\Rightarrow 𝑡$ is said to be monomorphic in the type variable $𝑎$ if $𝑎$ is free in $\forall \stackrel{<mtext>\_</mtext>}{𝑢}.\text{𝑐𝑥}\Rightarrow 𝑡$.

It is worth noting that the explicit type signatures provided by Haskell are not powerful enough to express types that include monomorphic type variables. For example, we cannot write

  f x = let 
          g :: a -> b -> ([a],b)
          g y z = ([x,y], z)
        in ...

because that would claim that g was polymorphic in both a and b (Section 4.4.1). In this program, g can only be given a type signature if its first argument is restricted to a type not involving type variables; for example

  g :: Int -> b -> ([Int],b)

This signature would also cause x to have type Int.

4.5.5 The Monomorphism Restriction

Haskell places certain extra restrictions on the generalization step, beyond the standard Hindley-Milner restriction described above, which further reduces polymorphism in particular cases.

The monomorphism restriction depends on the binding syntax of a variable. Recall that a variable is bound by either a function binding or a pattern binding, and that a simple pattern binding is a pattern binding in which the pattern consists of only a single variable (Section 4.4.3).

The following two rules define the monomorphism restriction:

Motivation Rule 1 is required for two reasons, both of which are fairly subtle.

• Rule 1 prevents computations from being unexpectedly repeated. For example, genericLength is a standard function (in library Data.List) whose type is given by

  genericLength :: Num a => [b] -> a

  Now consider the following expression:

  let { len = genericLength xs } in (len, len)

  It looks as if len should be computed only once, but without Rule 1 it might be computed twice, once at each of two different overloadings. If the programmer does actually wish the computation to be repeated, an explicit type signature may be added:

  let { len :: Num a => a; len = genericLength xs } in (len, len)

• Rule 1 prevents ambiguity. For example, consider the declaration group

  [(n,s)] = reads t

  Recall that reads is a standard function whose type is given by the signature

  reads :: (Read a) => String -> [(a,String)]

  Without Rule 1, n would be assigned the type $\forall 𝑎.\text{𝚁𝚎𝚊𝚍}𝑎\Rightarrow 𝑎\to 𝑎$ and s the type $\forall 𝑎.\text{𝚁𝚎𝚊𝚍}𝑎\Rightarrow \text{𝚂𝚝𝚛𝚒𝚗𝚐}$. The latter is an invalid type, because it is inherently ambiguous. It is not possible to determine at what overloading to use s, nor can this be solved by adding a type signature for s. Hence, when non-simple pattern bindings are used (Section 4.4.3.2), the types inferred are always monomorphic in their constrained type variables, irrespective of whether a type signature is provided. In this case, both n and s are monomorphic in $𝑎$.

  The same constraint applies to pattern-bound functions. For example, in

  (f,g) = ((+),(-))

  both f and g are monomorphic regardless of any type signatures supplied for f or g.

Rule 2 is required because there is no way to enforce monomorphic use of an exported binding, except by performing type inference on modules outside the current module. Rule 2 states that the exact types of all the variables bound in a module must be determined by that module alone, and not by any modules that import it.

  module M1(len1) where
    default( Int, Double )
    len1 = genericLength "Hello"

  module M2 where
    import M1(len1)
    len2 = (2*len1) :: Rational

When type inference on module M1 is complete, len1 has the monomorphic type Num a => a (by Rule 1). Rule 2 now states that the monomorphic type variable a is ambiguous, and must be resolved using the defaulting rules of Section 4.3.4. Hence, len1 gets type Int, and its use in len2 is type-incorrect. (If the above code is actually what is wanted, a type signature on len1 would solve the problem.)

This issue does not arise for nested bindings, because their entire scope is visible to the compiler.

Consequences The monomorphism rule has a number of consequences for the programmer. Anything defined with function syntax usually generalizes as a function is expected to. Thus in

  f x y = x+y

the function f may be used at any overloading in class Num. There is no danger of recomputation here. However, the same function defined with pattern syntax:

  f = \x -> \y -> x+y

requires a type signature if f is to be fully overloaded. Many functions are most naturally defined using simple pattern bindings; the user must be careful to affix these with type signatures to retain full overloading. The standard prelude contains many examples of this:

  sum  :: (Num a) => [a] -> a
  sum  =  foldl (+) 0  

Rule 1 applies to both top-level and nested definitions. Consider

  module M where
    len1 = genericLength "Hello"
    len2 = (2*len1) :: Rational

Here, type inference finds that len1 has the monomorphic type (Num a => a); and the type variable a is resolved to Rational when performing type inference on len2.

4.6 Kind Inference

This section describes the rules that are used to perform kind inference, i.e. to calculate a suitable kind for each type constructor and class appearing in a given program.

The first step in the kind inference process is to arrange the set of datatype, synonym, and class definitions into dependency groups. This can be achieved in much the same way as the dependency analysis for value declarations that was described in Section 4.5.1. For example, the following program fragment includes the definition of a datatype constructor D, a synonym S and a class C, all of which would be included in the same dependency group:

  data C a => D a = Foo (S a)
  type S a = [D a]
  class C a where
      bar :: a -> D a -> Bool

The kinds of variables, constructors, and classes within each group are determined using standard techniques of type inference and kind-preserving unification [6]. For example, in the definitions above, the parameter a appears as an argument of the function constructor (->) in the type of bar and hence must have kind $\ast$. It follows that both D and S must have kind $\ast \to \ast$ and that every instance of class C must have kind $\ast$.

It is possible that some parts of an inferred kind may not be fully determined by the corresponding definitions; in such cases, a default of $\ast$ is assumed. For example, we could assume an arbitrary kind $𝜅$ for the a parameter in each of the following examples:

  data App f a = A (f a)
  data Tree a  = Leaf | Fork (Tree a) (Tree a)

This would give kinds $\left(𝜅\to \ast \right)\to 𝜅\to \ast$ and $𝜅\to \ast$ for App and Tree, respectively, for any kind $𝜅$, and would require an extension to allow polymorphic kinds. Instead, using the default binding $𝜅=\ast$, the actual kinds for these two constructors are $\left(\ast \to \ast \right)\to \ast \to \ast$ and $\ast \to \ast$, respectively.

Defaults are applied to each dependency group without consideration of the ways in which particular type constructor constants or classes are used in later dependency groups or elsewhere in the program. For example, adding the following definition to those above does not influence the kind inferred for Tree (by changing it to $\left(\ast \to \ast \right)\to \ast$, for instance), and instead generates a static error because the kind of [], $\ast \to \ast$, does not match the kind $\ast$ that is expected for an argument of Tree:

  type FunnyTree = Tree []     -- invalid

This is important because it ensures that each constructor and class are used consistently with the same kind whenever they are in scope.